nixos/flake.nix

{
  description = "Deployment for skynet";

  inputs = {
    # gonna start off with a fairly modern base
    nixpkgs.url = "nixpkgs/nixos-unstable";
    # Return to using unstable once the current master is merged in
    # nixpkgs.url = "nixpkgs/nixos-unstable";

    # utility stuff
    flake-utils.url = "github:numtide/flake-utils";
    agenix.url = "github:ryantm/agenix";
    arion.url = "github:hercules-ci/arion";
    alejandra = {
      url = "github:kamadorueda/alejandra";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    colmena.url = "github:zhaofengli/colmena";

    # we host our own
    simple-nixos-mailserver = {
      inputs.nixpkgs.follows = "nixpkgs";
      url = "git+https://forgejo.skynet.ie/Skynet/misc_nixos-mailserver";
    };

    ######################
    ### skynet backend ###
    ######################
    skynet_ldap_backend.url = "git+https://forgejo.skynet.ie/Skynet/ldap_backend";
    #    skynet_ldap_backend.url = "git+file:/_college/CompSoc/Skynet/ldap_backend?shallow=1";
    skynet_ldap_frontend.url = "git+https://forgejo.skynet.ie/Skynet/ldap_frontend";
    skynet_website_wiki.url = "git+https://forgejo.skynet.ie/Skynet/wiki";
    skynet_website_games.url = "git+https://forgejo.skynet.ie/Skynet/website_games";
    skynet_discord_bot.url = "git+https://forgejo.skynet.ie/Skynet/discord-bot";
    skynet_discord_bot_t-800.url = "git+https://forgejo.skynet.ie/Skynet/discord-bot-t-800";
    # for testing a local build
    # skynet_discord_bot.url = "git+file:/_college/CompSoc/Skynet/discord_bot?shallow=1";

    #####################
    ### compsoc stuff ###
    #####################
    compsoc_public.url = "git+https://forgejo.skynet.ie/Computer_Society/presentations_compsoc";

    #################
    ### skynet.ie ###
    #################

    # this should always point to teh current website
    skynet_website.url = "git+https://forgejo.skynet.ie/Skynet/website_2023";

    # past versions of the current website
    skynet_website_2024.url = "git+https://forgejo.skynet.ie/Skynet/website_2023?ref=main&rev=8987e33cb709e7f2c30017e77edf9161b87d9885";
    skynet_website_2023.url = "git+https://forgejo.skynet.ie/Skynet/website_2023?ref=main&rev=c4d61c753292bf73ed41b47b1607cfc92a82a191";
    skynet_website_2022.url = "git+https://forgejo.skynet.ie/Skynet/website_2023?ref=2022&rev=687a0b1811987cfc27c2e6f5a625c4d59ef577c2";

    skynet_website_2016.url = "git+https://forgejo.skynet.ie/Skynet/website_2016";
    skynet_website_2006.url = "git+https://forgejo.skynet.ie/Skynet/website_2006";
    skynet_website_2003.url = "git+https://forgejo.skynet.ie/Skynet/website_2003";
    skynet_website_1996.url = "git+https://forgejo.skynet.ie/Skynet/website_1996";
  };

  nixConfig = {
    extra-substituters = "https://nix-cache.skynet.ie/skynet-cache";
    extra-trusted-public-keys = "skynet-cache:zMFLzcRZPhUpjXUy8SF8Cf7KGAZwo98SKrzeXvdWABo=";
  };

  outputs = {
    self,
    nixpkgs,
    agenix,
    alejandra,
    colmena,
    ...
  } @ inputs: let
    pkgs = nixpkgs.legacyPackages.x86_64-linux.pkgs;
  in {
    formatter.x86_64-linux = alejandra.defaultPackage."x86_64-linux";

    devShells.x86_64-linux.default = pkgs.mkShell {
      name = "Skynet";
      nativeBuildInputs = [
        pkgs.buildPackages.git
        colmena.defaultPackage."x86_64-linux"
        pkgs.attic-client
        pkgs.buildPackages.nmap
      ];
      buildInputs = [agenix.packages.x86_64-linux.default];
      shellHook = ''export PROMPT_DIRTRIM=3; export PS1="[Skynet] \w:\$ "'';
    };

    colmena = {
      meta = {
        nixpkgs = import nixpkgs {
          system = "x86_64-linux";
          overlays = [
            (final: prev: {
              inherit
                (final.lixPackageSets.stable)
                nixpkgs-review
                nix-direnv
                nix-eval-jobs
                nix-fast-build
                colmena
                ;
            })
          ];
        };
        specialArgs = {
          inherit inputs self;
        };
      };

      # installed for each machine
      defaults = import ./machines/_base.nix;

      # firewall machiene
      agentjones = import ./machines/agentjones.nix;

      # ns1
      vendetta = import ./machines/vendetta.nix;

      # ns2
      vigil = import ./machines/vigil.nix;

      # icecast - ULFM
      galatea = import ./machines/galatea.nix;

      # LDAP host
      kitt = import ./machines/kitt.nix;

      # Gitlab
      glados = import ./machines/glados.nix;

      # Gitlab runners
      wheatly = import ./machines/wheatly.nix;

      # email
      gir = import ./machines/gir.nix;

      # backup 1
      neuromancer = import ./machines/neuromancer.nix;

      # Skynet, user ssh access
      skynet = import ./machines/skynet.nix;

      # Main skynet sites
      earth = import ./machines/earth.nix;

      # Nextcloud
      cadie = import ./machines/cadie.nix;

      # trainee server
      marvin = import ./machines/marvin.nix;

      # Public Services
      calculon = import ./machines/calculon.nix;

      # metrics
      ariia = import ./machines/ariia.nix;

      # games server - panel
      optimus = import ./machines/optimus.nix;

      # games server - host
      bumblebee = import ./machines/bumblebee.nix;
    };
  };
}