nixos/applications/bitwarden/_bitwarden-directory-connector.nix

{
  lib,
  buildNpmPackage,
  fetchFromGitHub,
  pkgs,
  git,
  python3,
  pkg-config,
  libsecret,
  nodejs_18,
}: let
  buildNpmPackage' = buildNpmPackage.override {nodejs = nodejs_18;};
in
  buildNpmPackage' rec {
    pname = "bitwarden-directory-connector";
    version = "2023.10.0";

    src = fetchFromGitHub {
      owner = "bitwarden";
      repo = "directory-connector";
      rev = "b2bc45137013b258bffda2c2703715cb9f6e687f";
      hash = "sha256-CgaCnMWNVWCJBypNcdoseVCwD8Mlq4YaWpK+VZT/7Qk=";
      leaveDotGit = true;
    };

    npmDepsHash = "sha256-jBAWWY12qeX2EDhUvT3TQpnQvYXRsIilRrXGpVzxYvw=";

    env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";

    makeCacheWritable = true;
    npmBuildScript = "build:cli:prod";

    installPhase = ''
      mkdir -p $out
      cp -R {build-cli,node_modules} $out
    '';

    buildInputs = [
      libsecret
    ];

    nativeBuildInputs = [
      git
      python3
      pkg-config
    ];

    meta = with lib; {
      description = "A LDAP connector for Bitwarden";
      homepage = "https://github.com/bitwarden/directory-connector";
      license = licenses.gpl3Only;
      maintainers = with maintainers; [Silver-Golden];
      platforms = platforms.linux;
    };
  }